Console MOTD 1.0

BlackSignature · 8 Фев 2025

BlackSignature добавил(а) новый ресурс:

Console MOTD - MOTD-сообщение в консоли игрока при входе на сервер

Простой плагин для вывода MOTD-сообщения в консоль игрока при входе на сервер

Узнать больше об этом ресурсе...

MayroN · 8 Фев 2025

BlackSignature Я так понял engclient_print быстрее выполняется,чем client_print ?

BlackSignature · 8 Фев 2025

MayroN, в каком контексте "быстрее" ? он тут для того, чтобы не было проблем отображения при открытом vgui / motd

GALAXY · 9 Фев 2025

1. После захода на сервер инфа в консоле отображается 2 секунды, после чего вся информация с консоли пропадает. Конфликт у меня с чем-то или у всех так?
2. Есть возможность сделать отображение в цветном варианте?

Первый пункт исправил задержкой в 10 секунд.

BiZaJe · 11 Фев 2025

Код:

#include amxmodx
#include amxmisc

new const PLUGIN_NAME[] = "Console MOTD"
new const PLUGIN_VERSION[] = "1.0"

// Config filename in 'amxmodx/configs'.
new const CFG_FILENAME[] = "console_motd.ini"

// Maximum of console message rows. Can be changed if needed.
const MAX_STRINGS = 10

// Delay between logging into the server and displaying the message. Can be changed if needed.
const Float:MSG_DELAY = 1.0

const MSG_LEN = 256

new g_szMotdRow[MAX_STRINGS][MSG_LEN], g_iMsgCount

public plugin_init() {
    register_plugin(PLUGIN_NAME, PLUGIN_VERSION, "mx?!")
    
    new szBuffer[MSG_LEN]
    new iLen = get_configsdir(szBuffer, charsmax(szBuffer))
    formatex(szBuffer[iLen], charsmax(szBuffer) - iLen, "/%s", CFG_FILENAME)
    new hFile = fopen(szBuffer, "r")
    
    if(!hFile) {
        set_fail_state("Can't %s '%s'", file_exists(szBuffer) ? "read" : "find", szBuffer)
        return
    }
    
    while(fgets(hFile, szBuffer, charsmax(szBuffer))) {
        trim(szBuffer)
        
        if(!szBuffer[0] || szBuffer[0] == ';' || szBuffer[0] == '/') {
            continue
        }
        
+      if(strlen(szBuffer) >= MSG_LEN) {
+            continue
+      }

        replace_string(szBuffer, charsmax(szBuffer), "<br>", "^n")
        
        copy(g_szMotdRow[g_iMsgCount], charsmax(g_szMotdRow[]), szBuffer)
        
        if(++g_iMsgCount == MAX_STRINGS) {
            break
        }
    }
    
    fclose(hFile)
    
    server_print("[%s] Loaded %i message rows", PLUGIN_NAME, g_iMsgCount)
    
    if(!g_iMsgCount) {
        pause("ad")
    }
}

public client_putinserver(pPlayer) {
    if(!is_user_bot(pPlayer) && !is_user_hltv(pPlayer)) {
        set_task(MSG_DELAY, "task_PrintMOTD", pPlayer)
    }
}

public client_disconnected(pPlayer) {
    remove_task(pPlayer)
}

public task_PrintMOTD(pPlayer) {
+  if(!is_user_connected (player)) {
+     return
+  }

    for(new i; i < g_iMsgCount; i++) {
        engclient_print(pPlayer, engprint_console, g_szMotdRow[i])
    }
}

Ещё бы добавить в set_fail_state более информативное сообщение

И по replace_string, а если попадут управляющие символы...

BlackSignature · 11 Фев 2025

BiZaJe, ?

Код:

new szBuffer[MSG_LEN]

+      if(strlen(szBuffer) >= MSG_LEN) {
+            continue
+      }

Куда уж информативнее?

Код:

   if(!hFile) {
        set_fail_state("Can't %s '%s'", file_exists(szBuffer) ? "read" : "find", szBuffer)
        return
    }

Я понимаю, что бывает кейс, когда disconnected в плагине может сработать раньше, чем putinserver в нём же, но это уже "синдром больной головы", не следует учитывать все возможные ошибки других авторов плагинов

Код:

public client_disconnected(pPlayer) {
    remove_task(pPlayer)
}

+  if(!is_user_connected (player)) {
+     return
+  }

Конкретнее бы. Не понял, что имеется ввиду

И по replace_string, а если попадут управляющие символы...

fl0wer · 11 Фев 2025

BlackSignature написал(а):
Я понимаю, что бывает кейс, когда disconnected в плагине может сработать раньше, чем putinserver в нём же, но это уже "синдром больной головы", не следует учитывать все возможные ошибки других авторов плагинов

Если зайти на сервер и выйти, до окончания таска (delay), будет ошибка. То есть это базовый кейс, который лучше обработать.

BlackSignature · 11 Фев 2025

fl0wer, падажжи, у меня же таск сетается в putinserver, а удаление таска в disconnected.

BiZaJe · 12 Фев 2025

BlackSignature, Да никто никого не троллит

В первом случае проверка длины массива чтобы после копирования не вылазить за пределы массива, думаю лишним не будет

Во втором случае проверка на подключённого игрока тоже не лишняя, но это уже выше расписали

Повторюсь, что всю мессагу отправленную в консоль лучше отфильтровать и экранировать символы \ " ; и т.д

Код:

#include amxmodx
#include amxmisc

new const PLUGIN_NAME[] = "Console MOTD"
new const PLUGIN_VERSION[] = "1.0"

// Config filename in 'amxmodx/configs'.
new const CFG_FILENAME[] = "console_motd.ini"

// Maximum of console message rows. Can be changed if needed.
const MAX_STRINGS = 10

// Delay between logging into the server and displaying the message. Can be changed if needed.
const Float:MSG_DELAY = 1.0

const MSG_LEN = 256

new g_szMotdRow[MAX_STRINGS][MSG_LEN], g_iMsgCount

public plugin_init() {
    register_plugin(PLUGIN_NAME, PLUGIN_VERSION, "mx?!")
    
    new szBuffer[MSG_LEN]
    new iLen = get_configsdir(szBuffer, charsmax(szBuffer))
-    formatex(szBuffer[iLen], charsmax(szBuffer) - iLen, "/%s", CFG_FILENAME)
+    formatex(szBuffer[iLen], charsmax(szBuffer) - iLen, "%s%s", (szBuffer[iLen-1] == '/') ? "" : "/", CFG_FILENAME)
    new hFile = fopen(szBuffer, "r")
    
    if(!hFile) {
        set_fail_state("Can't %s '%s'", file_exists(szBuffer) ? "read" : "find", szBuffer)
        return
    }
    
    while(fgets(hFile, szBuffer, charsmax(szBuffer))) {
        trim(szBuffer)
        
        if(!szBuffer[0] || szBuffer[0] == ';' || szBuffer[0] == '/') {
            continue
        }
        
+      if(strlen(szBuffer) >= MSG_LEN) {
+            continue
+      }

-        replace_string(szBuffer, charsmax(szBuffer), "<br>", "^n")
        
+       replace_string(szBuffer, charsmax(szBuffer), "<br>", "\n");

        copy(g_szMotdRow[g_iMsgCount], charsmax(g_szMotdRow[]), szBuffer)
        
        if(++g_iMsgCount == MAX_STRINGS) {
            break
        }
    }
    
    fclose(hFile)
    
    server_print("[%s] Loaded %i message rows", PLUGIN_NAME, g_iMsgCount)
    
    if(!g_iMsgCount) {
        pause("ad")
    }
}

public client_putinserver(pPlayer) {
    if(!is_user_bot(pPlayer) && !is_user_hltv(pPlayer)) {
        set_task(MSG_DELAY, "task_PrintMOTD", pPlayer)
    }
}

public client_disconnected(pPlayer) {
    remove_task(pPlayer)
}

public task_PrintMOTD(pPlayer) {
+  if(!is_user_connected (player)) {
+     return
+  }

    for(new i; i < g_iMsgCount; i++) {
        engclient_print(pPlayer, engprint_console, g_szMotdRow[i])
    }
}

Refresh · 12 Фев 2025

BiZaJe,

Код:

+      if(strlen(szBuffer) >= MSG_LEN) {
+            continue
+      }

Это не требуется. Переменная инициализирована нулями, при указании размера буфера используется charsmax, поэтому в конце массива будет всегда 0 и это условие никогда не выполнится, никогда. Второго предполагаемого сценария тоже никогда не случится, потому что он обнуляет task при дисконнекте.

А для того чтобы сработал ваш вариант кода replace_string(szBuffer, charsmax(szBuffer), "<br>", "\n"); нужно в компиляторе изменить управляющий символ, например, так #pragma ctrlchar \. По-умолчанию, очевидно, будет работать вариант автора.

В core.ini задаются пути до папок amxx статически и без "/" на конце, поэтому конструкция (szBuffer[iLen-1] == '/') ? "" : "/" всегда выдаст "".

А вот после set_fail_state() больше ничего не выполняется... так что return не понадобится. Но это все чепуха и "лизания яйцев", когда заняться нечем...

BiZaJe · 12 Фев 2025

Refresh, зайдет какой-нибудь "топовый" тех.админ добавить /\ в конце пути и что будем делать?

Если массив инцилизирован нулями и использует charsmax это вообще не говорит о возможности вылезти за пределы

На счет ^n и \n , на каких-то источниках говорят, что ^n для худа , \n для консоли

Я не буду спорить и разводить срач в теме, автор с "огромным" опытом разберётся